Meteo #4 - Cara Menyimpan Nilai Variabel GrADS ke File Teks/ASCII

Salah satu masalah yang seringkali dihadapi oleh para pengguna GrADS adalah pengolahan data dalam format teks. Contoh kasus, anda ingin mengolah data curah hujan TRMM atau GSMaP (dalam format binary atau NetCDF) dan menampilkannya ke dalam bentuk time series. Setelah grafik time series muncul di layar, anda mungkin berpikir, bagaimana kalau data hujan tadi dibandingkan dengan data time series yang lain, seperti indeks IOD atau NINO3.4. Masalahnya, format data indeks-indeks tadi adalah ASCII sedangkan data hujannya adalah binary. 

Ada dua cara, pertama, mengubah data time series indeks tadi ke format binary kemudian menampilkannya bersama data hujan di GrADS, atau yang kedua, mengubah data time series hujan tadi ke format ASCII, kemudian menampilkannya bersama data indeks di software lain seperti Excel atau Surfer. Saya lebih suka cara kedua. Alasannya jujur saja, Excel jauh lebih mudah digunakan dibanding GrADS. Opsi grafik di Excel juga lebih banyak. Jadi kita bisa menampilkan data time series dengan lebih mudah dan lebih menarik.

Pada tulisan kali ini, saya akan mengulas cara kedua, yaitu menyimpan data variabel atau hasil pengolahan pada GrADS ke dalam format file ASCII, sehingga bisa ditampilkan ke software statistik lain seperti Excel, Surfer, SPSS, atau sekedar Notepad.

Pertama, siapkan file data yang ingin anda buka atau olah dengan GrADS. Formatnya terserah, bisa plain binary, NetCDF, Grib, HDF atau yang lain. Yang penting masih bisa buka dengan GrADS.

Kedua, anda membutuhkan script fprintf.gs yang berisi fungsi untuk menyimpan argumen/variabel GrADS ke dalam file teks. Bila anda menggunakan OpenGrads di Windows, script ini berada dalam direktori C:\OpenGrADS\Contents\Resources\Scripts. Bila anda menggunakan GrADS di Linux (instalasi via Synaptic Package Manager), kemungkinan script ini belum tersedia. Bila memang belum ada, anda bisa menyalin script tersebut pada akhir tulisan ini.

Ketiga, tampilkan variabel atau hasil pengolahan data yang ingin anda simpan ke file ASCII. Misalnya, saya ingin menampilkan data time series dari data curah hujan harian GSMaP NRT di daerah 90E-110E, 10S-0S pada bulan Juni 2013.

ga-> open GSMaP_NRT.daily.00Z-23Z.ctl

ga-> set x 1

ga-> set y 1

ga-> set time 1jun2013 30jun2013

ga-> define chaave=tloop(aave(precip,lon=90,lon=110,lat=-10,lat=0))

ga-> d chaave

Normalnya, hasil yang akan muncul pada GrADS adalah seperti ini :

Langkah berikutnya, menyimpan data time series yang sudah ditampilkan GrADS ini ke file ASCII. Untuk melakukan hal tersebut, yang paling dibutuhkan adalah variabel atau argumen dari data yang ditampilkan sebelumnya, dalam hal ini adalah : chaave. 

Yang perlu diperhatikan, script fprintf.gs akan menyimpan isi dari variabel chaave tadi ke file teks dengan memanfaatkan perintah set gxout print dan set prnopts pada GrADS. Hal ini akan membuat GrADS mengubah mode grafik ke dalam mode teks, lalu menyimpan variabel/argumen GrADS ke file teks. Sebelum menggunakan script, tentukan format file teks yang anda inginkan dengan perintah set prnopts. Misalnya, saya ingin menyimpan isi variabel chaave ke data teks dengan 1 data per record (1 kolom per baris). Ketikkan :

ga-> set prnopts %g 1 1

Untuk info lebih lanjut tentang perintah set prnopts, silakan baca GrADS manual aja ya :-)

Langkah terakhir, tinggal jalankan script fprintf.gs dengan syntax :

fprintf <variabel/argumen> <nama file teks atau ASCII>

Untuk kasus kita, misal file ASCII-nya adalah testlagi.txt contohnya penulisannya adalah :

ga-> fprintf chaave testlagi.txt

Bila prosesnya lancar, GrADS akan menginfokan bahwa file teks tersebut berhasil dibuat. File tersebut sudah bisa dibuka dengan menggunakan software lain seperti Excel atau pengolah kata sederhana seperti Notepad.

Bila dibuka dengan Excel, lalu dibuat grafik hasilnya seperti ini : 

Selanjutnya anda bisa menambahkan data lain (misal indeks IOD dll) ke dalam grafik tersebut untuk analisis lebih lanjut. 

Mudah kan ? Semoga bermanfaat :-)

-------------------------------------------

Script fprintf.gs (copy setelah baris ini).

function fprintf(args)

* Command line argumets

* ---------------------

  expr = subwrd(args,1)

  file = subwrd(args,2)

  format = subwrd(args,3)

  numl = subwrd(args,4)

  numb = subwrd(args,5)

  u = subwrd(args,6)

  if ( file='' )

    say ''

    say 'NAME'

    say '     fprintf - print GrADS variables to a text file'

    say ''

    say 'SYNOPSIS'

    say '     fprintf  expr  txtFile  [format numl numb [u]]'

    say ''

    say 'DESCRIPTION'

    say '     Evaluates the contents of the GrADS expression *expr* writing'

    say '     its values to a formatted text file *txtFile*. On output, the'

    say '     number of values and the undef values are returned; a negative'

    say '     number of values signals an error condition.'

    say ''

    say '     Unlike the output of *set gxout print*, the resulting ASCII'

    say '     file has only the data values and *no header*.'

    say ''

    say 'OPTIONS'

    say '     The optional parameters are the same as the ones required by'

    say '     the GrADS command *set prnopts*, namely'

    say '     format   a C language template for formatting ASCII output.'

    say '              Default is %g.'

    say '     numl     number of values to print per record. Default is 8.'

    say '     numb     number of blanks to insert between values. Default is 1.'

    say '     u        print "Undef" instead of the numerical value for'

    say '              missing data.'

    say 'BUGS'

    say '     The GrADS expression cannot have spaces in it.'

    say ''    

    say 'COPYRIGHT'

    say '     This script has been placed in the public domain'

    say ''

    return

  endif

* Set the display environment and produce buffered ASCII output

* -------------------------------------------------------------

  'set gxout print'

  if ( format != '' )

    'set prnopts ' format ' ' numl ' ' numb ' ' u ' '

  endif

  'display ' expr

   if ( rc!=0 ); return -1; endif

*  Get rid of header line: Printing Grid -- 3358 Values -- Undef = 1e+20

*  but record number of values and undef values for later reference

*  ---------------------------------------------------------------------

   buffer = result

   i = 1; line = sublin(buffer,i)

   n = subwrd(line,4)

   undef = subwrd(line,9)

* Now write the data values to text file: first line...

* -----------------------------------------------------

  i = 2; line = sublin(buffer,i)

  if ( write_(file,line) > 0 ); return -2; endif

* Append subsequent lines

* -----------------------

  i = i + 1; line = sublin(buffer,i)

  while ( line != '' )

    if ( write_(file,line,append) != 0 ); return -3; endif 

    i = i + 1; line = sublin(buffer,i)

  endwhile

  if ( close(file) != 0 ); return -4; endif

* All done

* --------

  say 'wrote ' n ' values to file "' file '"'

  return n ' ' undef ' ' 

function write_(file,line)

   rc = write(file,line)

   return subwrd(rc,1)